Práce s objektem Session

<%@LANGUAGE=VBSCript%>
<!DOCTYPE HTML PUBLIC "-//W3C//DTD HTML 4.0 Transitional//EN">
<HTML>
<HEAD>
  <TITLE>Cvičení k ADO - (c) 2002 Doc. Ing. Radim Farana, CSc.</TITLE>
  <META http-equiv="Content-Type" content="text/html; charset=windows-1250">
  <META NAME="AUTHOR" CONTENT="Radim Farana">
  <META NAME="CONTENT" CONTENT="Cvičení z ADO - práce s objektem Session">
</HEAD>
<BODY text="#000000" bgcolor="#FFFFFF" link="green" vlink="darkgreen" alink="#FF0000">
<H1>Práce s objektem ASP - Session</H1>

<%
' Deklarace promennych (nepovinna)
Dim CRLF, Status

' Definice promennych
CRLF = Chr(13) & Chr(10)

' Prevezmeme pozadavek na cinnost
Status = Request.QueryString("Status")

' Rozhodneme se pro pozadovanou cinnost
Select Case Status
    Case "Login"
        Session.Contents("UserIP") = Request.ServerVariables("REMOTE_HOST")
        Response.Write "<H3 ALIGN='CENTER'>Your log-in has been accepted.</H3>" & CRLF
    Case "Make"
        If Not Session.Contents("UserIP") = Request.ServerVariables("REMOTE_HOST") Then
            Response.Write "<H3 ALIGN='CENTER'><FONT COLOR='Red'>You are not logged in the system!</FONT></H3>" & CRLF
        Else
            Response.Write "<H3 ALIGN='CENTER'>Hello current user! Actual server date and time is: " & Now & "</H3>" & CRLF
        End If
    Case "Logout"
        Session.Contents("UserIP") = ""
        Response.Write "<H3 ALIGN='CENTER'>Your log-in has been canceled.</H3>" & CRLF
    Case Else
        Response.Write "<H3 ALIGN='CENTER'>Unknown request Status=" & Status & "</H1>" & CRLF
End Select
%>

<HR>
<P ALIGN="CENTER"><A HREF="SessionStart.htm">Return to main menu</A></P>
</BODY>
</HTML>