Cvičení k ASP - (c) 2005 Ing. Petr Šrek, doc. Ing. Radim Farana, CSc.

<% Option Explicit 
	On error resume next
	Dim objLDAP   'Pomocny objekt. Slouzi k zjisteni jestli muzu s LDAP pracovat
	Dim objOpenDS 'Objekt pro autentifikaci pres rozhrani IADsOpenDSObject
	Dim cName, cPass, cKontext 'Barva textu u jmena, hesla a kontextu
	Dim strName 'Zadane jmeno
	Dim strPass 'Zadane heslo
	Dim strKontext 'Zadany kontext
	Dim strConnString 'Prihlasovaci retezec
	Dim strObjectName 'Cela cesta k objektu ve stromu
	Dim strOut 'vystupni odpoved
	Dim bExit   'Je mozno pokracovat dale?
%>
<html>
<head>
<title>Přihlášení do systému</title>
<LINK rel="stylesheet" type="text/css" href="css/css.css">
</head>

<body>
	<%
		'Pocatecni inicializace
		strOut = ""
		cName    = "black"
		cPass	 = "black"
		cKontext = "black"
		strName    = Request.Form("txtName")
		strPass    = Request.Form("txtPass")
		strKontext = Request.Form("selKontext")

		bExit = FALSE
		'Po odeslani formulare
		if Len(Request.Form("cmdSend")) then 'Odeslal jsem formular?
			'Zkontroluju spravnost zadani polozek
			if Len(strName) = 0 then
				strOut = "<br><br><h3 align=left>Zadej uživatelské jméno!!!</h3>"
				cName = "red"
				bExit = TRUE
			end if
			if Len(strPass) = 0 then
				strOut = strOut & "<h3 align=left>Zadej heslo!!!</h3>"
				cPass = "red"
				bExit = TRUE
			end if
			if Len(strKontext) = 0 then
				strOut = strOut & "<h3 align=left>Vyber kontext!!!</h3><br>"
				cKontext = "red"
				bExit = TRUE
			end if
			Set objLDAP = GetObject("LDAP:") 'Overim dostupnost LDAP providera
			if IsEmpty(objLDAP) then
				bExit = TRUE 
				strOut = strOut & "<h3 align=center>Nepřísupný LDAP provider!!!</h3><br>"
				strOut = strOut & "<h5 align=center>Zkontrolujte připojení k síti a akci opakujte.</h5><br>"
			end if
			'Pokud probehla kontorla uspesne, muzu pokracovat smele dale
			if bExit = FALSE then
				'Slozim prihlasovaci retezec
				select case strKontext
					case "Student"     strKontext="ou=stu,o=fs"
					case "Zamestnanci" strKontext="ou=352,ou=kat,o=fs" 'Doladit, vice kateder ...
				end select
				strConnString = "LDAP://ldap.vsb.cz/cn=" & strName & "," & strKontext
				strObjectName = "cn=" & strName & "," & strKontext
				'Pokusime se pripojit k danemu objektu
				Set objOpenDS = objLDAP.OpenDSObject(strConnString, strObjectName, strPass, &H200)
				if IsEmpty(objOpenDS) then
					strOut = strOut & "<br><br><p align=center><table width='90%'><tr><td colspan=3><h3 align=center>Nepodařilo se připojit k objektu!!!</h3></td></tr>"
					strOut = strOut & "<tr><td><h5 align=right> Hlásíte se k objektu: </td><td>  </td><td align=left><i>" & strConnString & "</i></td></tr>"
					strOut = strOut & "<tr><td><h5 align=right> Hlásíte se k objektu jako: </td><td>  </td><td align=left><i>" & strObjectName & "</i></td></tr></table></p>"
				else
					strOut = strOut & "<br><br><p align=center><table width='90%'><tr><td colspan=3><h3 align=center>Podařilo se připojit k objektu!!!</h3></td></tr>"
					strOut = strOut & "<tr><td><h5 align=right> Hlásíte se k objektu: </td><td>  </td><td align=left><i>" & strConnString & "</i></td></tr>"
					strOut = strOut & "<tr><td><h5 align=right> Hlásíte se k objektu jako: </td><td>  </td><td align=left><i>" & strObjectName & "</i></td></tr><table></p>"
				end if
			end if
		end if
	%>
	<h1 align="center">Přihlašovací formulář</h1>
	<h3 align="center">Zadej své přihlašovací jméno a heslo!</h3><br><br>
	<form id="myForm" method="post" name="myForm" action="LDAPTest.asp">
		<p align="center">
		<table width="50%">
			<tr><td class="<% Response.Write(cName) %>"> Uživatelské jméno: </td>
				<td><input id="txtName" name="txtName" size="5" value="<% =strName %>"></td> 
			</tr>
			<tr><td class="<% Response.Write(cPass) %>"> Heslo: </td>
				<td><input type="password" id="txtPass" name="txtPass"></td>
			</tr>
			<tr><td class="<% Response.Write(cKontext) %>"> Kontext: </td>
				<td><SELECT id="selKontext" name="selKontext">
						<OPTION>Student</OPTION>
						<OPTION>Zamestnanci</OPTION>
					</SELECT></td>
			</tr>
			<tr><td colspan="2" align="center"><input id=cmdSend type="submit" value="Přihlásit"  name="cmdSend"></td></tr>
		</table>
		</p>
	</form><hr>
	
	<% 
		if bExit = TRUE then
			Response.Write "<font size=2>Upozornění</font><br>" & strOut
		else
			Response.Write "<font size=2>Výsledek</font><br>" & strOut
		end if
	%>
</body >
</html>